Little Joe had a board with AT89C52 clocked at 24MHz, with a 62256-type 32Kx8bit static RAM attached, addresses A0-A7 from P0 via a 74LS573 latch (latched by ALE, /OE pin permanently grounded), addresses A8-A14 connected to P2.0-P2.6, data bus connected to P0; /CS connected to P2.7 (A15); /WE connected to /WR; /OE connected to /PSEN and /RD which are ANDed together via two 74LS00-gates (the first NANDs the signals together while the second inverts the result to get the required AND function). This should map the memory to addresses 8000h-FFFFh in both external data and code memory space; so that a program can be uploaded to the RAM and executed from it.
There is a green LED (OK) connected to P1.0 and a red LED (ERROR) to P1.1 both by cathodes, both anodes via series 470Ω resistor to V_CC=5V. Little Joe reads 8052.com forum regularly, so he used also a three-legged reset generator.

Little Joe wrote the following test:

LED_OK      EQU   P1.0
LED_ERROR   EQU   P1.1
RAM         EQU   8000h
Test:
   mov   dptr,#RAM                ;set destination address
   mov   r2,dph
   mov   r3,dpl                   ;and store it
   mov   dptr,#RAMTest            ;set source address
   mov   r7,#RAMTestEnd-RAMTest   ;set counter
Loop:
   clr   a
   movc  a,@a+dptr                ;get source byte
   mov   r6,a                     ;store it temporarily
   inc   dptr                     ;advance source address
   mov   r4,dph
   mov   r5,dpl                   ;store source address
   mov   dph,r2
   mov   dpl,r3                   ;restore destination address
   movx  @dptr,a                  ;store byte to destination
   movx  a,@dptr                  ;readback byte from RAM
   xrl   a,r6                     ;test if stored in RAM correctly
   jnz   Error
   inc   dptr                     ;advance destination address
   mov   r2,dph
   mov   r3,dpl
   mov   dph,r4
   mov   dpl,r5                   ;exchange src/dest addresses
   djnz  r7,Loop                  ;loop for all bytes
   ljmp  RAM                      ;execute code in RAM

Error:
   clr   LED_ERROR                ;in case of error, red LED lit
   sjmp  Error                    ;and stay looping forever

RAMTest:
   clr   LED_OK                   ;turn on green LED
   ljmp  RAMTest                  ;and stay looping forever
RAMTestEnd:
   end

Little Joe assembled this program, burned it into AT89C52 using a device programmer. Upon powerup, BOTH LEDs turn immediately ON.

What has happened?

Jan Waclawek